Estrategia dirigida bandas de Bollinger

Definición

"Dirección de la estrategia" especifica qué tipos de órdenes puede crear la estrategia. Si el valor de ajuste es 0, puede indicar tanto una orden de compra como de venta. Si el ajuste es -1 sólo puede colocarse en venta y si es 1 sólo puede colocarse en compra. La dirección de la estrategia de las bandas de Bollinger indica una orden de compra cuando el símbolo cruza por debajo de la banda inferior de las bandas de Bollinger y una orden de venta si el símbolo cruza por encima de la banda superior. Pero recuerde que en los ajustes de la estrategia puede ajustar la dirección para que sea sólo una orden en compra, sólo en venta o ambas.

Cálculos

Pine Script

//@version=5
strategy("Bollinger Bands Strategy directed", overlay=true)
source = close
length = input.int(20, minval=1)
mult = input.float(2.0, minval=0.001, maxval=50)
direction = input.int(0, title = "Strategy Direction", minval=-1, maxval=1)
strategy.risk.allow_entry_in(direction == 0 ? strategy.direction.all : (direction < 0 ? strategy.direction.short : strategy.direction.long))
basis = ta.sma(source, length)
dev = mult * ta.stdev(source, length)
upper = basis + dev
lower = basis - dev
if (ta.crossover(source, lower))
    strategy.entry("BBandLE", strategy.long, stop=lower, oca_name="BollingerBands", oca_type=strategy.oca.cancel, comment="BBandLE")
else
    strategy.cancel(id="BBandLE")
if (ta.crossunder(source, upper))
    strategy.entry("BBandSE", strategy.short, stop=upper, oca_name="BollingerBands", oca_type=strategy.oca.cancel, comment="BBandSE")
else
    strategy.cancel(id="BBandSE")
//plot(strategy.equity, title="equity", color=color.red, linewidth=2, style=plot.style_areabr)

Resumen

La Estrategia dirigida bandas de Bollinger se creó para dar señales de compra o de venta cuando un símbolo se encuentra potencialmente por encima de su precio medio. Por ejemplo, la estrategia puede indicar comprar si un símbolo cae por debajo de su banda Bollinger inferior o vender si supera su banda Bollinger superior. Algunos traders podrían considerar esto como una reversión a la media porque las Bandas de Bollinger se crean utilizando una desviación estándar del precio medio del símbolo. Recuerde, la estrategia es dirigida y en los ajustes puede controlar el valor, es decir, si es 0 será tanto una orden de compra como de venta. Si el ajuste es -1 sólo podrá indicar venta y si es 1 sólo podrá indicar compra.